build: migrate to Kotlin DSL (#151)

Co-authored-by: PatrickMis <24607131+PatrickMis@users.noreply.github.com>

app/.gitignore

@@ -1 +1 @@
-/build
+/build

app/build.gradle

@@ -1,44 +0,0 @@
-plugins {
-    id 'com.android.application'
-    id 'org.jetbrains.kotlin.android'
-}
-
-android {
-    compileSdk 32
-    buildToolsVersion "32.0.0"
-    namespace 'app.revanced.integrations'
-
-    defaultConfig {
-        applicationId "app.revanced.integrations"
-        minSdk 23
-        targetSdk 32
-        versionCode 1
-        versionName "1.0"
-        multiDexEnabled false
-
-        Properties properties = new Properties()
-        if (rootProject.file("local.properties").exists()) {
-            properties.load(rootProject.file("local.properties").newDataInputStream())
-        }
-
-        buildConfigField "String", "YT_API_KEY", "\"${properties.getProperty("youtubeAPIKey", "")}\""
-    }
-
-    buildTypes {
-        release {
-            minifyEnabled false
-            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
-        }
-    }
-    compileOptions {
-        sourceCompatibility JavaVersion.VERSION_11
-        targetCompatibility JavaVersion.VERSION_11
-    }
-    kotlinOptions {
-        jvmTarget = '11'
-    }
-}
-
-dependencies {
-    compileOnly 'androidx.annotation:annotation:1.5.0'
-}

app/build.gradle.kts

@@ -0,0 +1,47 @@
+import java.io.FileInputStream
+import java.util.Properties
+
+plugins {
+    id("com.android.application")
+    id("org.jetbrains.kotlin.android")
+}
+
+android {
+    compileSdk = 32
+    buildToolsVersion = "32.0.0"
+    namespace = "app.revanced.integrations"
+
+    defaultConfig {
+        applicationId = "app.revanced.integrations"
+        minSdk = 23
+        targetSdk = 32
+        versionCode = 1
+        versionName = "1.0"
+        multiDexEnabled = false
+
+        val properties = Properties()
+        if (rootProject.file("local.properties").exists()) {
+            properties.load(FileInputStream(rootProject.file("local.properties")))
+        }
+
+        buildConfigField("String", "YT_API_KEY", "\"${properties.getProperty("youtubeAPIKey", "")}\"")
+    }
+
+    buildTypes {
+        release {
+            isMinifyEnabled = false
+            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
+        }
+    }
+    compileOptions {
+        sourceCompatibility(JavaVersion.VERSION_11)
+        targetCompatibility(JavaVersion.VERSION_11)
+    }
+    kotlinOptions {
+        jvmTarget = JavaVersion.VERSION_11.toString()
+    }
+}
+
+dependencies {
+    compileOnly("androidx.annotation:annotation:1.5.0")
+}

app/proguard-rules.pro

@@ -18,4 +18,4 @@
 
 # If you keep the line number information, uncomment this to
 # hide the original source file name.
-#-renamesourcefileattribute SourceFile
+#-renamesourcefileattribute SourceFile

app/src/main/AndroidManifest.xml

@@ -2,4 +2,4 @@
 
     <uses-permission android:name="android.permission.ACCESS_NETWORK_STATE" />
     <uses-permission android:name="android.permission.SCHEDULE_EXACT_ALARM" />
-</manifest>
+</manifest>